Unable to use count, for_each, or depends_on arguments even on 3.0.0-pre1

[CRASH-Tech]

Terraform, Provider, Kubernetes and Helm Versions

Terraform version: 1.10.4
Provider version: 3.0.0-pre1
Kubernetes version: 1.27.7

Terraform Configuration Files

terraform {
  required_providers {
    helm = {
      source  = "hashicorp/helm"
      version = "3.0.0-pre1"
    }
  }
}

provider "helm" {
  kubernetes {
    host                   = yamldecode(var.kubeconfig).clusters[0].cluster.server
    cluster_ca_certificate = base64decode(yamldecode(var.kubeconfig).clusters[0].cluster.certificate-authority-data)
    client_certificate     = base64decode(yamldecode(var.kubeconfig).users[0].user.client-certificate-data)
    client_key             = base64decode(yamldecode(var.kubeconfig).users[0].user.client-key-data)
  }
}

module "cilium" {
  source     = "../../../../../modules/helm-release"
  depends_on = [module.talos-cluster]

  kubeconfig = module.talos-cluster.kubeconfig
}

Debug Output

The module at module.cilium is a legacy module which contains its own local provider configurations, and so calls to it may not use the count, for_each, or depends_on arguments.
│ 
│ If you also control the module "../../../../../modules/helm-release", consider updating this module to instead expect provider configurations to be passed by its caller.

References

• Migrate to terraform plugin framework #1379

[JaylonmcShan03]

Hi @CRASH-Tech I believe the error you're seeing is related to how provider configurations are handled inside modules. In Terraform, when a module contains its own provider block, it's treated as a "legacy module" — and Terraform doesn’t allow using count, for_each, or depends_on on modules like that.

To fix this, the provider configuration for helm should be moved outside the module and passed explicitly using providers.

provider "helm" {
  alias = "cilium"

  kubernetes {
    host                   = yamldecode(var.kubeconfig).clusters[0].cluster.server
    cluster_ca_certificate = base64decode(yamldecode(var.kubeconfig).clusters[0].cluster.certificate-authority-data)
    client_certificate     = base64decode(yamldecode(var.kubeconfig).users[0].user.client-certificate-data)
    client_key             = base64decode(yamldecode(var.kubeconfig).users[0].user.client-key-data)
  }
}

module "cilium" {
  source     = "../../../../../modules/helm-release"
  depends_on = [module.talos-cluster]

  kubeconfig = module.talos-cluster.kubeconfig

  providers = {
    helm = helm.cilium
  }
}