Applying `sumsquares()` on the Ouput of a Infinity Norm Fails

[RoyiAvital]

I am trying to optimize:

$$ \sum_{i = 1}^{n} {\left\| \boldsymbol{a}_{i} - \boldsymbol{x} \right\|}_{\infty}^{2} $$

Yet Convex.sumsquares() fails on the vector of values of ${\left\| \boldsymbol{a}_{i} - \boldsymbol{x} \right\|}_{\infty}^{2}$.
If I use sum() and not sumsquares() it works.
See code to replicate.

## Packages
using Convex;
using ECOS;

## Functions

function SolveProblemConvex( mA :: Matrix{T} ) where {T <: AbstractFloat}

    dataDim    = size(mA, 1);
    numSamples = size(mA, 2);

    vX = Variable(dataDim);

    vV        = [Convex.norm_inf(vX - mA[:, ii]) for ii ∈ 1:numSamples];
    sConvProb = minimize( Convex.sumsquares(vV) ); #<! Does not work
    # sConvProb = minimize( Convex.sum(vV) ); #<! Works
    
    Convex.solve!(sConvProb, ECOS.Optimizer; silent = true);

    return vX.value;
    
end

## Parameters
dataDim    = 5;
numSamples = 10;

## Data
mA = randn(dataDim, numSamples);

## Analysis
vX = SolveProblemConvex(mA);

[odow]

For reference, the "doesn't work' is a MethodError:

julia> using Convex

julia> data = randn(2, 2)
2×2 Matrix{Float64}:
  0.90205   -1.11294
 -0.199509   0.686573

julia> m, n = size(data)
(2, 2)

julia> X = Variable(m)
Variable
size: (2, 1)
sign: real
vexity: affine
id: 354…998

julia> V = [Convex.norm_inf(X - data[:, ii]) for ii in 1:n]
2-element Vector{Convex.MaximumAtom}:
 maximum (convex; positive)
└─ abs (convex; positive)
   └─ + (affine; real)
      ├─ 2-element real variable (id: 354…998)
      └─ [-0.90205; 0.199509;;]
 maximum (convex; positive)
└─ abs (convex; positive)
   └─ + (affine; real)
      ├─ 2-element real variable (id: 354…998)
      └─ [1.11294; -0.686573;;]

julia> sumsquares(V)
ERROR: MethodError: no method matching sumsquares(::Vector{Convex.MaximumAtom})

Closest candidates are:
  sumsquares(::Convex.AbstractExpr)
   @ Convex ~/.julia/packages/Convex/IPPoR/src/supported_operations.jl:2175

Stacktrace:
 [1] top-level scope
   @ REPL[28]:1

It's because we define only

Convex.jl/src/supported_operations.jl

Lines 2154 to 2180 in 6daf81c

	"""
	sumsquares(x::AbstractExpr)
	The epigraph of \$||x||_2^2\$.
	## Examples
	Applies to a single matrix
	```jldoctest; filter=r"id: [0-9]+…[0-9]+"
	julia> x = Variable(3);
	julia> atom = sumsquares(x)
	qol (convex; positive)
	├─ 3-element real variable (id: 125…181)
	└─ [1;;]
	julia> size(atom)
	(1, 1)
	```
	"""
	function sumsquares(x::AbstractExpr)
	if size(x, 2) != 1
	return QuadOverLinAtom(reshape(x, length(x), 1), constant(1))
	end
	return QuadOverLinAtom(x, constant(1))
	end

so calling sumsquares(::Vector) doesn't have a fallback.

The solution is to create a vcat object:

julia> sumsquares(vcat(V...))
qol (convex; positive)
├─ vcat (convex; positive)
│  ├─ maximum (convex; positive)
│  │  └─ abs (convex; positive)
│  │     └─ …
│  └─ maximum (convex; positive)
│     └─ abs (convex; positive)
│        └─ …
└─ [1;;]

This is an unfortunate but intended consequence of Convex.jl's MATLAB-ism of using AbtractExpr instead of Base.AbstractArray.

Your sum works because it falls back to the generic +:

julia> sum(V)
+ (convex; positive)
├─ maximum (convex; positive)
│  └─ abs (convex; positive)
│     └─ + (affine; real)
│        ├─ …
│        └─ …
└─ maximum (convex; positive)
   └─ abs (convex; positive)
      └─ + (affine; real)
         ├─ …
         └─ …

julia> @which sum(V)
sum(a::AbstractArray; dims, kw...)
     @ Base reducedim.jl:1012

[RoyiAvital]

OK, I just followed the lines of the Optimal Advertising example on how to have an objective defined by a loop:

# Form and solve the optimal advertising problem.
using Convex, SCS;
D = Variable(m, n);
Si = [min(R[i] * dot(P[i, :], D[i, :]'), B[i]) for i in 1:m];
problem =
    maximize(sum(Si), [D >= 0, sum(D, dims = 1)' <= T, sum(D, dims = 2) >= c]);
solve!(problem, SCS.Optimizer; silent = true)

Hence I thought the vector of expressions created can be used in other atoms.
So the solution is is just use vcat() on the vector.

[odow]

So the solution is is just use vcat() on the vector.

Yes. This applies to all of Convex.jl, not just sumsquares, so I'm hesitant to fix this one case.

That sum works is an unintended consequence of Julia's fallback dispatch. It's not an explicit feature of Convex.jl.

[RoyiAvital]

Indeed. Hence I think the example above should be converted into vcat() as the use of sum() is misleading.

[odow]

I made a PR here: #723

Don't hesitate to open a PR (or issue) if you have other suggestions for improving the docs 😄

[RoyiAvital]

I'd be happy to push such PR.
Just prefer to coordinate it with you as before.

Anyhow, thanks for the fast solution.