[cmake] use `PCL::` target for imported targets of PCL

[kai-waang]

PCL currently provides imported targets without namespacing (e.g., pcl_common, pcl_io, pcl_visualization), rather than using PackageName::Component naming conventions (e.g., PCL::common, PCL::io, PCL::visualization), which is commonly seen in many packages (Eigen3, Boost, VTK...)

If so, we can write:

find_package(PCL REQUIRED COMPONENTS io common)
target_link_libraries(foo PCL::io PCL::common)

or we can even have a target PCL::PCL to include all imported targets.

[mvieth]

Thank you for the suggestion, I think that is a good idea. We can probably create alias-targets, so that e.g. pcl_common can also be used under the name PCL::common. I do not know when I will have the time to implement this, though, but feel free to take a look at PCLConfig.cmake.in in the meantime.

[kai-waang]

I think the easiest way to do this is to create alias target PCL::component after this:

pcl/PCLConfig.cmake.in

Lines 633 to 653 in 4db3dc4

	if(_is_header_only EQUAL -1)
	add_library(${pcl_component} @PCL_LIB_TYPE@ IMPORTED)
	if(PCL_${COMPONENT}_LIBRARY_DEBUG)
	set_target_properties(${pcl_component}
	PROPERTIES
	IMPORTED_CONFIGURATIONS "RELEASE;DEBUG"
	IMPORTED_LOCATION_RELEASE "${PCL_${COMPONENT}_LIBRARY}"
	IMPORTED_LOCATION_DEBUG "${PCL_${COMPONENT}_LIBRARY_DEBUG}"
	IMPORTED_IMPLIB_RELEASE "${PCL_${COMPONENT}_LIBRARY}"
	IMPORTED_IMPLIB_DEBUG "${PCL_${COMPONENT}_LIBRARY_DEBUG}"
	)
	else()
	set_target_properties(${pcl_component}
	PROPERTIES
	IMPORTED_LOCATION "${PCL_${COMPONENT}_LIBRARY}"
	IMPORTED_IMPLIB "${PCL_${COMPONENT}_LIBRARY}"
	)
	endif()
	else() # header-only
	add_library(${pcl_component} INTERFACE IMPORTED)
	endif()

Maybe we can create a alias target like this (after line 653):

    add_library(PCL::${component} INTERFACE IMPORTED)

    if(PCL_${COMPONENT}_INCLUDE_DIRS)
      set_target_properties(PCL::${component}
        PROPERTIES
          INTERFACE_INCLUDE_DIRECTORIES "${PCL_${COMPONENT}_INCLUDE_DIRS};${PCL_CONF_INCLUDE_DIR}"
      )
    endif()

    if(CMAKE_VERSION VERSION_LESS 3.11)
      set_target_properties(PCL::${component}
        PROPERTIES INTERFACE_LINK_LIBRARIES ${PCL_${COMPONENT}_LINK_LIBRARIES}
      )
    else()
      target_link_libraries(PCL::${component} INTERFACE ${PCL_${COMPONENT}_LINK_LIBRARIES})
    endif()

[mvieth]

I was thinking of an actual CMake alias-target as described here: https://cmake.org/cmake/help/latest/command/add_library.html#alias-libraries
So probably something like add_library(PCL::${component} ALIAS ${pcl_component})

[kai-waang]

Yes, but need to first check the cmake version, because we can't create a alias target for a imported target in CMake<3.18. so maybe something like this:

    if(CMAKE_VERSION VERSION_LESS 3.18.0)
      add_library(PCL::${component} INTERFACE IMPORTED)
      target_link_libraries(PCL::${component} INTERFACE ${pcl_component})
    else()
      add_library(PCL::${component} ALIAS ${pcl_component})
    endif()

[mvieth]

Ah yes, you are right, the libraries are non-global imported targets. I thought they are global imported targets, then it would have worked in CMake 3.11 already.