Update test aspect to fix last_green build

Updates `_aspect_impl()` in `test/aspect/aspect.bzl` to return a new
`VisitedInfo` provider instead of a `struct`. This fixes
`//test/aspect:aspect_test` when building with the `last_green` bazel:

- bazel-a91a6a77171c008598bdee53d144792c95211890-darwin-arm64

```txt
$ USE_BAZEL_VERSION=last_green \
  bazel test --test_output=errors //test/aspect:aspect_test

ERROR: testing/toolchain/BUILD:10:27:
  in //test/aspect:aspect.bzl%test_aspect aspect
  on testing_toolchain_deps rule //testing/toolchain:junit_classpath:
  Returning a struct from an aspect implementation function is deprecated.

ERROR: Analysis of target '//testing/toolchain:junit_classpath' failed
ERROR: Analysis of target '//test/aspect:aspect_test' failed; build aborted: Analysis failed
```

This `last_green` Bazel build contains the following commit, summarized
as "Remove support for returning struct providers from aspects":

- bazelbuild/bazel@07cddaf

That commit is related to:

- bazelbuild/bazel#25836
- bazelbuild/bazel#25819
- bazelbuild/intellij#7606

Author: mbland

test/aspect/aspect.bzl

@@ -5,6 +5,8 @@ sure the targets we expect are there.
 """
 attr_aspects = ["_scala_toolchain", "deps"]
 
+VisitedInfo = provider("Collection of visited targets", fields = ["visited"])
+
 def _stringify_label(label):
     s = str(label)
     if s.startswith("@@//"):
@@ -15,12 +17,12 @@ def _stringify_label(label):
 
 def _aspect_impl(target, ctx):
     visited = [_stringify_label(target.label)]
+
     for attr_name in attr_aspects:
-        if hasattr(ctx.rule.attr, attr_name):
-            for dep in getattr(ctx.rule.attr, attr_name):
-                if hasattr(dep, "visited"):
-                    visited += dep.visited
-    return struct(visited = visited)
+        for dep in getattr(ctx.rule.attr, attr_name, []):
+            visited += dep[VisitedInfo].visited
+
+    return VisitedInfo(visited = visited)
 
 test_aspect = aspect(
     attr_aspects = attr_aspects,
@@ -56,7 +58,7 @@ def _aspect_testscript_impl(ctx):
     }
     content = ""
     for target in ctx.attr.targets:
-        visited = depset(sorted(target.visited)).to_list()
+        visited = depset(sorted(target[VisitedInfo].visited)).to_list()
         expected = depset(sorted(expected_deps[target.label.name])).to_list()
         if visited != expected:
             content += """
@@ -71,12 +73,12 @@ def _aspect_testscript_impl(ctx):
                 visited = ", ".join(visited),
             )
 
-    scriptFile = ctx.actions.declare_file("aspect_test.sh")
+    script_file = ctx.actions.declare_file("aspect_test.sh")
     ctx.actions.write(
-        output = scriptFile,
+        output = script_file,
         content = content,
     )
-    return [DefaultInfo(files = depset([scriptFile]))]
+    return [DefaultInfo(files = depset([script_file]))]
 
 aspect_testscript = rule(
     implementation = _aspect_testscript_impl,