[bazel] Add module_extension support to gcs_mirror

Unfortunately we can't load() gcs_mirror.bzl into MODULE.bazel. The
cleanest way to get around this is to use a module_extension which wraps
http_archive and http_file.

Bug: b/458681039
Change-Id: I6116db1b9927a6083afe8b23ce2e49ee705188ce
Reviewed-on: https://skia-review.googlesource.com/c/buildbot/+/1125497
Reviewed-by: Brett Somocurcio <[email protected]>
Commit-Queue: Eric Boren <[email protected]>

Author: erock2112

MODULE.bazel

@@ -27,6 +27,8 @@ http_archive = use_repo_rule("@bazel_tools//tools/build_defs/repo:http.bzl", "ht
 
 http_file = use_repo_rule("@bazel_tools//tools/build_defs/repo:http.bzl", "http_file")
 
+gcs_mirror = use_extension("//bazel:gcs_mirror.bzl", "gcs_mirror")
+
 ####################################################################################################
 # aspect_rules_ts setup
 ####################################################################################################
@@ -584,19 +586,21 @@ PROTOC_BUILD_FILE_CONTENT = """
 exports_files(["bin/protoc"], visibility = ["//visibility:public"])
 """
 
-http_archive(
+gcs_mirror.http_archive(
     name = "protoc_linux_x64",
     build_file_content = PROTOC_BUILD_FILE_CONTENT,
     sha256 = "3a4c1e5f2516c639d3079b1586e703fc7bcfa2136d58bda24d1d54f949c315e8",
     url = "https://github.com/protocolbuffers/protobuf/releases/download/v21.12/protoc-21.12-linux-x86_64.zip",
 )
+use_repo(gcs_mirror, "protoc_linux_x64")
 
-http_archive(
+gcs_mirror.http_archive(
     name = "protoc_mac_x64",
     build_file_content = PROTOC_BUILD_FILE_CONTENT,
     sha256 = "9448ff40278504a7ae5139bb70c962acc78c32d8fc54b4890a55c14c68b9d10a",
     url = "https://github.com/protocolbuffers/protobuf/releases/download/v21.12/protoc-21.12-osx-x86_64.zip",
 )
+use_repo(gcs_mirror, "protoc_mac_x64")
 
 ####################################################################################################
 # pgadapter.
@@ -618,7 +622,7 @@ filegroup(
 # CockroachDB (used as an "emulator" for tests).
 ####################################################################################################
 
-http_archive(
+gcs_mirror.http_archive(
     name = "cockroachdb_linux",
     build_file_content = """
 filegroup(
@@ -627,12 +631,11 @@ filegroup(
     visibility = ["//visibility:public"]
 )
 """,
-    # https://www.cockroachlabs.com/docs/v21.1/install-cockroachdb-linux does not currently
-    # provide SHA256 signatures. kjlubick@ downloaded this file and computed this sha256 signature.
     sha256 = "05293e76dfb6443790117b6c6c05b1152038b49c83bd4345589e15ced8717be3",
     strip_prefix = "cockroach-v21.1.9.linux-amd64",
     url = "https://binaries.cockroachdb.com/cockroach-v21.1.9.linux-amd64.tgz",
 )
+use_repo(gcs_mirror, "cockroachdb_linux")
 
 ####################################################################################################
 # bazel-toolchains rbe_configs_gen (prebuilt).
@@ -653,13 +656,15 @@ rbe_exec_properties = use_extension("//bazel/external:rbe_exec_properties.bzl",
 rbe_exec_properties.setup(name = "exec_properties")
 use_repo(rbe_exec_properties, "exec_properties")
 
-http_file(
+gcs_mirror.http_file(
     name = "rbe_configs_gen_linux_amd64",
     downloaded_file_path = "rbe_configs_gen",
     executable = True,
+    no_extension = True,
     sha256 = "1206e8a79b41cb22524f73afa4f4ee648478f46ef6990d78e7cc953665a1db89",
     url = "https://github.com/bazelbuild/bazel-toolchains/releases/download/v5.1.2/rbe_configs_gen_linux_amd64",
 )
+use_repo(gcs_mirror, "rbe_configs_gen_linux_amd64")
 
 ####################################################################################################
 # Google Cloud SDK (needed for the Google Cloud Emulators).

MODULE.bazel.lock

@@ -1,5 +1,7 @@
 """This module provides the gcs_mirror_url macro."""
 
+load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive", "http_file")
+
 # Set to True to force the macro to only return the mirror URL.
 _TEST_GCS_MIRROR = False
 
@@ -37,3 +39,62 @@ def gcs_mirror_url(url, sha256, ext = None):
 
     mirror_url = "%s/%s%s" % (_GCS_MIRROR_PREFIX, sha256, extension)
     return [mirror_url] if _TEST_GCS_MIRROR else [mirror_url, url]
+
+def _gcs_mirror_impl(ctx):
+    def _url_helper(tag):
+        # This is a weird effect resulting from the combination of
+        # gcs_mirror_url treatment of None vs "" and the fact that
+        # attrs.string() cannot be None.
+        ext = tag.ext
+        if tag.no_extension:
+            ext = ""
+        elif tag.ext == "":
+            ext = None
+        return gcs_mirror_url(tag.url, tag.sha256, ext)
+
+    for mod in ctx.modules:
+        for tag in mod.tags.http_archive:
+            http_archive(
+                name = tag.name,
+                build_file_content = tag.build_file_content,
+                sha256 = tag.sha256,
+                strip_prefix = tag.strip_prefix,
+                urls = _url_helper(tag),
+            )
+        for tag in mod.tags.http_file:
+            http_file(
+                name = tag.name,
+                downloaded_file_path = tag.downloaded_file_path,
+                executable = tag.executable,
+                sha256 = tag.sha256,
+                urls = _url_helper(tag),
+            )
+
+_http_archive = tag_class(attrs = {
+    "name": attr.string(),
+    "build_file_content": attr.string(),
+    "ext": attr.string(),
+    "no_extension": attr.bool(),
+    "url": attr.string(),
+    "sha256": attr.string(),
+    "strip_prefix": attr.string(),
+})
+
+_http_file = tag_class(attrs = {
+    "name": attr.string(),
+    "downloaded_file_path": attr.string(),
+    "executable": attr.bool(),
+    "ext": attr.string(),
+    "no_extension": attr.bool(),
+    "sha256": attr.string(),
+    "url": attr.string(),
+})
+
+gcs_mirror = module_extension(
+    doc = """Bzlmod extension wrapper around gcs_mirror_url.""",
+    implementation = _gcs_mirror_impl,
+    tag_classes = {
+        "http_archive": _http_archive,
+        "http_file": _http_file,
+    },
+)