chore(libsinsp): add target to build library for sinsp integration tests

Signed-off-by: irozzo-1A <[email protected]>

Author: irozzo-1A

.github/workflows/ci.yml

@@ -42,11 +42,12 @@ jobs:
 
       - name: Install a recent version of CMake ⛓️
         run: |
-          curl -L -o /tmp/cmake.tar.gz https://github.com/Kitware/CMake/releases/download/v3.22.5/cmake-3.22.5-linux-$(uname -m).tar.gz
+          CMAKE_VERSION=3.24.4
+          curl -L -o /tmp/cmake.tar.gz https://github.com/Kitware/CMake/releases/download/v${CMAKE_VERSION}/cmake-${CMAKE_VERSION}-linux-$(uname -m).tar.gz
           gzip -d /tmp/cmake.tar.gz
           tar -xpf /tmp/cmake.tar --directory=/tmp
-          cp -R /tmp/cmake-3.22.5-linux-$(uname -m)/* /usr
-          rm -rf /tmp/cmake-3.22.5-linux-$(uname -m)/
+          cp -R /tmp/cmake-${CMAKE_VERSION}-linux-$(uname -m)/* /usr
+          rm -rf /tmp/cmake-${CMAKE_VERSION}-linux-$(uname -m)/
 
       - name: Checkout Libs ⤵️
         uses: actions/checkout@8e8c483db84b4bee98b60c0593521ed34d9990e8 # v6.0.1

CMakeLists.txt

@@ -30,7 +30,7 @@ if(EXISTS ${CMAKE_CURRENT_BINARY_DIR}/CMakeLists.txt)
 	)
 endif()
 
-cmake_minimum_required(VERSION 3.12)
+cmake_minimum_required(VERSION 3.24)
 
 # Enable MACOSX_RPATH (and keep CMake from complaining).
 if(POLICY CMP0042)

cmake/modules/gtest.cmake

@@ -18,64 +18,18 @@ option(USE_BUNDLED_GTEST "Enable building of the bundled gtest" ${USE_BUNDLED_DE
 if(GTEST_INCLUDE_DIR)
 	# we already have gtest
 elseif(NOT USE_BUNDLED_GTEST)
-	find_path(
-		GTEST_INCLUDE_DIR
-		PATH_SUFFIXES gtest
-		NAMES gtest.h
-	)
-	find_library(GTEST_LIB NAMES gtest)
-	find_library(GTEST_MAIN_LIB NAMES gtest_main)
-	if(GTEST_INCLUDE_DIR
-	   AND GTEST_LIB
-	   AND GTEST_MAIN_LIB
-	)
-		message(
-			STATUS
-				"Found gtest: include: ${GTEST_INCLUDE_DIR}, lib: ${GTEST_LIB}, main lib: ${GTEST_MAIN_LIB}"
-		)
-	else()
-		message(FATAL_ERROR "Couldn't find system gtest")
-	endif()
+	find_package(GTest REQUIRED)
 else()
-	# https://github.com/google/googletest/tree/main/googletest#incorporating-into-an-existing-cmake-project
-	# Download and unpack googletest at configure time
-	configure_file(
-		CMakeListsGtestInclude.cmake ${PROJECT_BINARY_DIR}/googletest-download/CMakeLists.txt
-	)
-	execute_process(
-		COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" .
-		RESULT_VARIABLE result
-		WORKING_DIRECTORY ${PROJECT_BINARY_DIR}/googletest-download
-	)
-	if(result)
-		message(FATAL_ERROR "CMake step for googletest failed: ${result}")
-	endif()
-	execute_process(
-		COMMAND ${CMAKE_COMMAND} --build .
-		RESULT_VARIABLE result
-		WORKING_DIRECTORY ${PROJECT_BINARY_DIR}/googletest-download
-	)
-	if(result)
-		message(FATAL_ERROR "Build step for googletest failed: ${result}")
-	endif()
-
-	# Add googletest directly to our build. This defines the gtest and gtest_main targets.
-	add_subdirectory(
-		${PROJECT_BINARY_DIR}/googletest-src ${PROJECT_BINARY_DIR}/googletest-build
-		EXCLUDE_FROM_ALL
-	)
-
-	set(GTEST_INCLUDE_DIR "${gtest_SOURCE_DIR}/include")
-	set(GTEST_MAIN_LIB "gtest_main")
-	install(
-		DIRECTORY "${GTEST_INCLUDE_DIR}"
-		DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${LIBS_PACKAGE_NAME}"
-		COMPONENT "libs-deps"
+	include(FetchContent)
+	FetchContent_Declare(
+		gtest
+		URL https://github.com/google/googletest/archive/refs/tags/v1.16.0.tar.gz
+		URL_HASH SHA256=78c676fc63881529bf97bf9d45948d905a66833fbfa5318ea2cd7478cb98f399
+		OVERRIDE_FIND_PACKAGE
 	)
+	FetchContent_MakeAvailable(gtest)
 endif()
 
 if(NOT TARGET gtest)
 	add_custom_target(gtest)
 endif()
-
-include_directories("${GTEST_INCLUDE_DIR}")

test/drivers/CMakeLists.txt

@@ -1,5 +1,7 @@
 message(STATUS "Drivers tests build enabled")
 
+find_package(GTest REQUIRED)
+
 # Configure ia32 action test
 option(ENABLE_IA32_TESTS "Enable ia32 tests. Require ia32 glibc and gcc." ON)
 if(ENABLE_IA32_TESTS)
@@ -45,7 +47,7 @@ set(DRIVERS_TEST_SOURCES
 
 set(DRIVERS_TEST_INCLUDE PRIVATE "${GTEST_INCLUDE}" "${LIBS_DIR}/driver/" "${LIBSCAP_INCLUDE_DIRS}")
 
-set(DRIVERS_TEST_LINK_LIBRARIES scap "${GTEST_LIB}" "${GTEST_MAIN_LIB}")
+set(DRIVERS_TEST_LINK_LIBRARIES scap GTest::gtest GTest::gtest_main)
 
 set(DRIVERS_TEST_DEPENDECIES scap gtest)
 

test/libscap/CMakeLists.txt

@@ -39,7 +39,7 @@ set(LIBSCAP_TESTS_INCLUDE
 # Needed by gtest
 find_package(Threads)
 
-set(LIBSCAP_TESTS_LIBRARIES "${GTEST_LIB}" "${GTEST_MAIN_LIB}" "${CMAKE_THREAD_LIBS_INIT}" scap)
+set(LIBSCAP_TESTS_LIBRARIES GTest::gtest GTest::gtest_main scap)
 
 set(LIBSCAP_TESTS_DEPENDENCIES gtest scap)
 

test/libsinsp_e2e/CMakeLists.txt

@@ -15,6 +15,7 @@
 
 message(STATUS "Libsinsp unit e2e tests build enabled")
 
+find_package(GTest REQUIRED)
 if(NOT DEFINED DRIVER_NAME)
 	set(DRIVER_NAME "scap")
 endif()
@@ -57,7 +58,7 @@ else()
 	add_dependencies(libsinsp_e2e_tests driver)
 endif()
 
-target_link_libraries(libsinsp_e2e_tests sinsp "${GTEST_LIB}" "${GTEST_MAIN_LIB}" pthread)
+target_link_libraries(libsinsp_e2e_tests sinsp GTest::gtest GTest::gtest_main pthread)
 
 target_include_directories(
 	libsinsp_e2e_tests PRIVATE ${PROJECT_BINARY_DIR}/driver/src "${CMAKE_CURRENT_BINARY_DIR}"

userspace/libsinsp/test/CMakeLists.txt

@@ -11,7 +11,7 @@
 # is distributed on an "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express
 # or implied. See the License for the specific language governing permissions and limitations under
 # the License.
-#
+find_package(GTest REQUIRED)
 
 include(jsoncpp)
 if(NOT EMSCRIPTEN)
@@ -30,6 +30,26 @@ configure_file(
 	"${CMAKE_CURRENT_BINARY_DIR}/libsinsp_test_var.h"
 )
 
+file(GLOB_RECURSE TEST_HELPERS CONFIGURE_DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/helpers/*.cpp)
+
+# sinsp_test_support library to be used to run integration tests in other projects (e.g., plugins)
+add_library(sinsp_test_support STATIC sinsp_with_test_input.cpp test_utils.cpp "${TEST_HELPERS}")
+
+target_include_directories(
+	sinsp_test_support
+	PUBLIC ${LIBS_DIR} # needed for driver/event_stats.h
+		   ${CMAKE_CURRENT_BINARY_DIR} # needed for libsinsp_test_var.h
+		   ${CMAKE_CURRENT_SOURCE_DIR} ${UTHASH_INCLUDE} ${JSONCPP_INCLUDE}
+)
+
+target_link_libraries(sinsp_test_support PUBLIC sinsp GTest::gtest "${JSONCPP_LIB}")
+
+add_dependencies(sinsp_test_support uthash)
+
+if(NOT EMSCRIPTEN)
+	target_link_libraries(sinsp_test_support PUBLIC "${TBB_LIB}")
+endif()
+
 file(GLOB_RECURSE TEST_PLUGINS CONFIGURE_DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/plugins/*.cpp)
 
 if(NOT WIN32)
@@ -48,8 +68,11 @@ endif()
 
 option(SCAP_FILES_SUITE_ENABLE "Enable scap-file tests in sinsp" "ON")
 # Scap-files on Big Endian systems are not supported
-if((NOT ${CMAKE_HOST_SYSTEM_PROCESSOR} STREQUAL "s390x") AND ${SCAP_FILES_SUITE_ENABLE})
-	# Binary dir in which we will save all our Cmake files
+if((NOT ${CMAKE_HOST_SYSTEM_PROCESSOR} STREQUAL "s390x")
+   AND ${SCAP_FILES_SUITE_ENABLE}
+   AND TARGET unit-test-libsinsp
+)
+	# Binary dir in which we will save all our scap files
 	file(MAKE_DIRECTORY "${CMAKE_BINARY_DIR}/scap_files")
 	# Add here the name for new scap-files
 	set(SCAP_FILE_NAMES
@@ -66,22 +89,20 @@ if((NOT ${CMAKE_HOST_SYSTEM_PROCESSOR} STREQUAL "s390x") AND ${SCAP_FILES_SUITE_
 	)
 	message(STATUS "Download all scap-files from: ${SCAP_FILE_DOWNLOAD_PREFIX}")
 	foreach(FILE_NAME ${SCAP_FILE_NAMES})
-		message(STATUS "Downloading scap-file: ${SCAP_FILE_DOWNLOAD_PREFIX}/${FILE_NAME}")
 		if(NOT EXISTS "${CMAKE_BINARY_DIR}/scap_files/${FILE_NAME}")
+			message(STATUS "Downloading scap-file: ${FILE_NAME}")
 			file(DOWNLOAD "${SCAP_FILE_DOWNLOAD_PREFIX}/${FILE_NAME}"
 				 "${CMAKE_BINARY_DIR}/scap_files/${FILE_NAME}" SHOW_PROGRESS
 			)
 		else()
-			message(STATUS "Skipping download, file already present")
+			message(STATUS "Skipping download, file already present: ${FILE_NAME}")
 		endif()
 	endforeach()
 	file(GLOB_RECURSE SCAP_FILES_SUITE CONFIGURE_DEPENDS
 		 ${CMAKE_CURRENT_SOURCE_DIR}/scap_files/*.cpp
 	)
 endif()
 
-file(GLOB_RECURSE TEST_HELPERS CONFIGURE_DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/helpers/*.cpp)
-
 set(LIBSINSP_UNIT_TESTS_SOURCES
 	ast_exprs.ut.cpp
 	test_utils.cpp
@@ -196,9 +217,14 @@ target_include_directories(
 			${CMAKE_CURRENT_SOURCE_DIR}
 )
 
-target_link_libraries(
-	unit-test-libsinsp sinsp "${GTEST_LIB}" "${GTEST_MAIN_LIB}" "${TBB_LIB}" "${JSONCPP_LIB}"
-)
+# Link against sinsp and gtest - using both old-style variables and new targets for compatibility
+if(NOT EMSCRIPTEN)
+	target_link_libraries(
+		unit-test-libsinsp sinsp GTest::gtest GTest::gtest_main "${TBB_LIB}" "${JSONCPP_LIB}"
+	)
+else()
+	target_link_libraries(unit-test-libsinsp sinsp GTest::gtest GTest::gtest_main "${JSONCPP_LIB}")
+endif()
 
 # Add some additional include directories associated with `ADDITIONAL_SINSP_TESTS_SUITE`
 # `ADDITIONAL_SINSP_TESTS_INCLUDE_FOLDERS` is a list of include paths `;` separated