refactor native animated to pass folly::dynamic to fabric (#51335)

Summary:
Pull Request resolved: #51335

## Changelog:
[iOS][Breaking] - synchronouslyUpdateViewOnUIThread now accepts folly::dynamic instead of NSDictionary. Use https://github.com/facebook/react-native/blob/main/packages/react-native/ReactCommon/react/utils/platform/ios/react/utils/FollyConvert.h#L14 for conversion.

pass folly::dynamic directly from native animated since Fabric consumes folly::dynamic for direct manipulation.
Additionally, remove return value from `synchronouslyUpdateViewOnUIThread` as it was never used.

Reviewed By: lenaic, zeyap

Differential Revision: D74738548

fbshipit-source-id: a3f1373bb0c643e8dcfb3e065edbcad42aa5d4d7

Author: sammy-SC

packages/react-native/Libraries/NativeAnimation/Nodes/RCTPropsAnimatedNode.mm

@@ -13,6 +13,7 @@
 #import <React/RCTStyleAnimatedNode.h>
 #import <React/RCTUIManager.h>
 #import <React/RCTValueAnimatedNode.h>
+#import <react/utils/FollyConvert.h>
 
 @implementation RCTPropsAnimatedNode {
   NSNumber *_connectedViewTag;
@@ -61,9 +62,12 @@ - (void)updateView
 {
   if (_managedByFabric) {
     if (_bridge.surfacePresenter) {
-      [_bridge.surfacePresenter synchronouslyUpdateViewOnUIThread:_connectedViewTag props:_propsDictionary];
+      [_bridge.surfacePresenter
+          synchronouslyUpdateViewOnUIThread:_connectedViewTag.integerValue
+                                      props:facebook::react::convertIdToFollyDynamic(_propsDictionary)];
     } else {
-      [_surfacePresenter synchronouslyUpdateViewOnUIThread:_connectedViewTag props:_propsDictionary];
+      [_surfacePresenter synchronouslyUpdateViewOnUIThread:_connectedViewTag.integerValue
+                                                     props:facebook::react::convertIdToFollyDynamic(_propsDictionary)];
     }
   } else {
     [_bridge.uiManager synchronouslyUpdateViewOnUIThread:_connectedViewTag

packages/react-native/Libraries/NativeAnimation/React-RCTAnimation.podspec

@@ -48,6 +48,7 @@ Pod::Spec.new do |s|
   add_dependency(s, "ReactCommon", :subspec => "turbomodule/core", :additional_framework_paths => ["react/nativemodule/core"])
   add_dependency(s, "React-NativeModulesApple")
   add_dependency(s, "React-featureflags")
+  add_dependency(s, "React-utils", :additional_framework_paths => ["react/utils/platform/ios"])
 
   add_rn_third_party_dependencies(s)
 end

packages/react-native/React/Base/RCTViewRegistry.m

@@ -5,7 +5,6 @@
  * LICENSE file in the root directory of this source tree.
  */
 
-#import <React/RCTSurfacePresenterStub.h>
 #import <React/RCTUIManager.h>
 
 #import "RCTBridge.h"

packages/react-native/React/CxxUtils/RCTFollyConvert.h

@@ -16,6 +16,7 @@ namespace facebook::react {
 folly::dynamic convertIdToFollyDynamic(id json);
 [[deprecated(
     "This function is deprecated, please use /ReactCommon/react/utils/platform/ios/react/utils/FollyConvert.h instead")]]
-id convertFollyDynamicToId(const folly::dynamic& dyn);
+id convertFollyDynamicToId(const folly::dynamic &dyn);
+NSArray<NSString *> *extractKeysFromFollyDynamic(const folly::dynamic &dyn);
 
 } // namespace facebook::react

packages/react-native/React/CxxUtils/RCTFollyConvert.mm

@@ -113,4 +113,20 @@ id convertFollyDynamicToId(const folly::dynamic &dyn)
   return nil;
 }
 
+NSArray<NSString *> *extractKeysFromFollyDynamic(const folly::dynamic &dyn)
+{
+  NSMutableArray<NSString *> *result = [NSMutableArray new];
+
+  if (dyn.type() == folly::dynamic::OBJECT) {
+    for (const auto &elem : dyn.items()) {
+      NSString *key = [[NSString alloc] initWithBytes:elem.first.c_str()
+                                               length:elem.first.size()
+                                             encoding:NSUTF8StringEncoding];
+      [result addObject:key];
+    }
+  }
+
+  return result;
+}
+
 } // namespace facebook::react

packages/react-native/React/Fabric/Mounting/RCTMountingManager.h

@@ -67,7 +67,7 @@ NS_ASSUME_NONNULL_BEGIN
            forShadowView:(const facebook::react::ShadowView &)shadowView;
 
 - (void)synchronouslyUpdateViewOnUIThread:(ReactTag)reactTag
-                             changedProps:(NSDictionary *)props
+                             changedProps:(folly::dynamic)props
                       componentDescriptor:(const facebook::react::ComponentDescriptor &)componentDescriptor;
 @end
 

packages/react-native/React/Fabric/Mounting/RCTMountingManager.mm

@@ -282,25 +282,34 @@ - (void)setIsJSResponder:(BOOL)isJSResponder
 }
 
 - (void)synchronouslyUpdateViewOnUIThread:(ReactTag)reactTag
-                             changedProps:(NSDictionary *)props
+                             changedProps:(folly::dynamic)props
                       componentDescriptor:(const ComponentDescriptor &)componentDescriptor
 {
   RCTAssertMainQueue();
+  NSArray<NSString *> *propsKeysToBeUpdated = extractKeysFromFollyDynamic(props);
+  bool updatesTransform = props.find("transform") != props.items().end();
+  bool updatesOpacity = props.find("opacity") != props.items().end();
+
   UIView<RCTComponentViewProtocol> *componentView = [_componentViewRegistry findComponentViewWithTag:reactTag];
+  if (!componentView) {
+    RCTLogWarn(@"Attempted to update view with tag %ld, but it no longer exists", (long)reactTag);
+    return;
+  }
+
   SurfaceId surfaceId = RCTSurfaceIdForView(componentView);
   Props::Shared oldProps = [componentView props];
   Props::Shared newProps = componentDescriptor.cloneProps(
-      PropsParserContext{surfaceId, *_contextContainer.get()}, oldProps, RawProps(convertIdToFollyDynamic(props)));
+      PropsParserContext{surfaceId, *_contextContainer.get()}, oldProps, RawProps(std::move(props)));
 
   NSSet<NSString *> *propKeys = componentView.propKeysManagedByAnimated_DO_NOT_USE_THIS_IS_BROKEN ?: [NSSet new];
-  propKeys = [propKeys setByAddingObjectsFromArray:props.allKeys];
+  propKeys = [propKeys setByAddingObjectsFromArray:propsKeysToBeUpdated];
   componentView.propKeysManagedByAnimated_DO_NOT_USE_THIS_IS_BROKEN = nil;
   [componentView updateProps:newProps oldProps:oldProps];
   componentView.propKeysManagedByAnimated_DO_NOT_USE_THIS_IS_BROKEN = propKeys;
 
   const auto &newViewProps = static_cast<const ViewProps &>(*newProps);
 
-  if (props[@"transform"]) {
+  if (updatesTransform) {
     auto layoutMetrics = LayoutMetrics();
     layoutMetrics.frame.size.width = componentView.layer.bounds.size.width;
     layoutMetrics.frame.size.height = componentView.layer.bounds.size.height;
@@ -309,7 +318,7 @@ - (void)synchronouslyUpdateViewOnUIThread:(ReactTag)reactTag
       componentView.layer.transform = newTransform;
     }
   }
-  if (props[@"opacity"] && componentView.layer.opacity != (float)newViewProps.opacity) {
+  if (updatesOpacity && componentView.layer.opacity != (float)newViewProps.opacity) {
     componentView.layer.opacity = newViewProps.opacity;
   }
 

packages/react-native/React/Fabric/RCTSurfacePresenter.h

@@ -65,7 +65,7 @@ NS_ASSUME_NONNULL_BEGIN
 
 - (nullable RCTFabricSurface *)surfaceForRootTag:(ReactTag)rootTag;
 
-- (BOOL)synchronouslyUpdateViewOnUIThread:(NSNumber *)reactTag props:(NSDictionary *)props;
+- (void)synchronouslyUpdateViewOnUIThread:(ReactTag)reactTag props:(folly::dynamic)props;
 
 - (void)setupAnimationDriverWithSurfaceHandler:(const facebook::react::SurfaceHandler &)surfaceHandler;
 

packages/react-native/React/Fabric/RCTSurfacePresenter.mm

@@ -148,28 +148,27 @@ - (UIView *)findComponentViewWithTag_DO_NOT_USE_DEPRECATED:(NSInteger)tag
   return componentView;
 }
 
-- (BOOL)synchronouslyUpdateViewOnUIThread:(NSNumber *)reactTag props:(NSDictionary *)props
+- (void)synchronouslyUpdateViewOnUIThread:(ReactTag)reactTag props:(folly::dynamic)props
 {
   RCTScheduler *scheduler = [self scheduler];
   if (!scheduler) {
-    return NO;
+    return;
   }
-
-  ReactTag tag = [reactTag integerValue];
   UIView<RCTComponentViewProtocol> *componentView =
-      [_mountingManager.componentViewRegistry findComponentViewWithTag:tag];
+      [_mountingManager.componentViewRegistry findComponentViewWithTag:reactTag];
   if (componentView == nil) {
-    return NO; // This view probably isn't managed by Fabric
+    return; // This view probably isn't managed by Fabric
   }
   ComponentHandle handle = [[componentView class] componentDescriptorProvider].handle;
   auto *componentDescriptor = [scheduler findComponentDescriptorByHandle_DO_NOT_USE_THIS_IS_BROKEN:handle];
 
   if (!componentDescriptor) {
-    return YES;
+    return;
   }
 
-  [_mountingManager synchronouslyUpdateViewOnUIThread:tag changedProps:props componentDescriptor:*componentDescriptor];
-  return YES;
+  [_mountingManager synchronouslyUpdateViewOnUIThread:reactTag
+                                         changedProps:std::move(props)
+                                  componentDescriptor:*componentDescriptor];
 }
 
 - (void)setupAnimationDriverWithSurfaceHandler:(const facebook::react::SurfaceHandler &)surfaceHandler

packages/react-native/React/Modules/RCTSurfacePresenterStub.h

@@ -9,6 +9,7 @@
 
 #import <React/RCTBridge.h>
 #import <React/RCTBridgeProxy.h>
+#import <folly/dynamic.h>
 
 @protocol RCTSurfaceProtocol;
 
@@ -32,7 +33,7 @@ NS_ASSUME_NONNULL_BEGIN
 - (id<RCTSurfaceProtocol>)createFabricSurfaceForModuleName:(NSString *)moduleName
                                          initialProperties:(NSDictionary *)initialProperties;
 - (nullable UIView *)findComponentViewWithTag_DO_NOT_USE_DEPRECATED:(NSInteger)tag;
-- (BOOL)synchronouslyUpdateViewOnUIThread:(NSNumber *)reactTag props:(NSDictionary *)props;
+- (void)synchronouslyUpdateViewOnUIThread:(NSInteger)reactTag props:(folly::dynamic)props;
 - (void)addObserver:(id<RCTSurfacePresenterObserver>)observer;
 - (void)removeObserver:(id<RCTSurfacePresenterObserver>)observer;