Creates _test_headers_not_passed_to_linking_action for cc_binary() in rules_cc/test/cc/common/cc_binary_configured_target_test.bzl

PiperOrigin-RevId: 879495530
Change-Id: I5c51be96e25da2c72cc7f9b999d7e9e5b282b5d4

Author: pzembrod

MODULE.bazel

@@ -26,7 +26,16 @@ single_version_override(
     version = "1.17.0",
 )
 
-bazel_dep(name = "rules_testing", version = "0.6.0", dev_dependency = True)
+# Required commit 288cdbd "Add meta field to ActionSubject."
+# TODO: pzembrod - Change to a released version again when the commit is in a release.
+bazel_dep(name = "rules_testing", dev_dependency = True)
+archive_override(
+    module_name = "rules_testing",
+    integrity = "sha256-7Uj90x7fnhUKBxRytq/R4E9gOBisIoDW1KoUxHCDVd4=",
+    strip_prefix = "rules_testing-288cdbd3ef4839a89d9d5911319fd9edde44b106",
+    urls = ["https://github.com/bazelbuild/rules_testing/archive/288cdbd3ef4839a89d9d5911319fd9edde44b106.tar.gz"],
+)
+
 bazel_dep(name = "stardoc", version = "0.8.0", dev_dependency = True)
 
 # Compatibility layer

WORKSPACE

@@ -37,11 +37,13 @@ rules_shell_dependencies()
 
 rules_shell_toolchains()
 
+# Required commit 288cdbd "Add meta field to ActionSubject."
+# TODO: pzembrod - Change to a released version again when the commit is in a release.
 http_archive(
     name = "rules_testing",
-    sha256 = "02c62574631876a4e3b02a1820cb51167bb9cdcdea2381b2fa9d9b8b11c407c4",
-    strip_prefix = "rules_testing-0.6.0",
-    url = "https://github.com/bazelbuild/rules_testing/releases/download/v0.6.0/rules_testing-v0.6.0.tar.gz",
+    integrity = "sha256-7Uj90x7fnhUKBxRytq/R4E9gOBisIoDW1KoUxHCDVd4=",
+    strip_prefix = "rules_testing-288cdbd3ef4839a89d9d5911319fd9edde44b106",
+    url = "https://github.com/bazelbuild/rules_testing/archive/288cdbd3ef4839a89d9d5911319fd9edde44b106.tar.gz",
 )
 
 http_archive(

tests/cc/common/cc_binary_configured_target_tests.bzl

@@ -1,46 +1,59 @@
 """Tests for cc_binary."""
 
-load("@rules_testing//lib:analysis_test.bzl", "analysis_test", "test_suite")
+load("@rules_testing//lib:truth.bzl", "matching")
 load("@rules_testing//lib:util.bzl", "util")
 load("//cc:cc_binary.bzl", "cc_binary")
+load("//tests/cc/testutil:cc_analysis_test.bzl", "cc_analysis_test", "cc_test_suite")
+load("//tests/cc/testutil:cc_binary_target_subject.bzl", "cc_binary_target_subject")
+load("//tests/cc/testutil:link_action_subject.bzl", "link_action_subject")
 
-def _test_files_to_build(name, binary_extension):
+def _test_files_to_build(name, **kwargs):
     util.helper_target(
         cc_binary,
         name = name + "/hello",
         srcs = ["hello.cc"],
     )
-    analysis_test(
+    cc_analysis_test(
         name = name,
         impl = _test_files_to_build_impl,
-        attrs = {
-            "binary_extension": attr.string(),
-        },
-        attr_values = {
-            "binary_extension": binary_extension,
-        },
         target = name + "/hello",
+        **kwargs
     )
 
 def _test_files_to_build_impl(env, target):
-    expected_extension = env.ctx.attr.binary_extension
-    expected_name = "{package}/{name}".format(
-        package = target.label.package,
-        name = target.label.name,
-    ) + expected_extension
-    env.expect.that_target(target).default_outputs().contains_exactly([expected_name])
-    env.expect.that_target(target).executable().short_path_equals(expected_name)
+    cc_binary_subject = cc_binary_target_subject.from_target(env, target)
+    cc_binary_subject.default_outputs().contains_exactly(["{package}/{name}{binary_extension}"])
+    cc_binary_subject.executable().short_path_equals("{package}/{name}{binary_extension}")
+
+def _test_headers_not_passed_to_linking_action(name, **kwargs):
+    util.helper_target(
+        cc_binary,
+        name = name + "/bye",
+        srcs = ["bye.cc", "bye.h"],
+    )
+    cc_analysis_test(
+        name = name,
+        impl = _test_headers_not_passed_to_linking_action_impl,
+        target = name + "/bye",
+        config_settings = {
+            "//command_line_option:features": ["parse_headers"],
+            "//command_line_option:process_headers_in_dependencies": True,
+        },
+        **kwargs
+    )
+
+def _test_headers_not_passed_to_linking_action_impl(env, target):
+    link_action_subject.from_target(env, target).inputs().contains_none_of([
+        matching.str_endswith(".h"),
+        matching.str_endswith(".hpp"),
+        matching.str_endswith(".hxx"),
+    ])
 
 def cc_binary_configured_target_tests(name):
-    test_suite(
+    cc_test_suite(
         name = name,
         tests = [
             _test_files_to_build,
+            _test_headers_not_passed_to_linking_action,
         ],
-        test_kwargs = {
-            "binary_extension": select({
-                "@platforms//os:windows": ".exe",
-                "//conditions:default": "",
-            }),
-        },
     )

tests/cc/testutil/BUILD

@@ -0,0 +1,29 @@
+"""Specialized analysis_test and test_suite for rules_cc."""
+
+load("@rules_testing//lib:analysis_test.bzl", "analysis_test", "test_suite")
+
+def cc_analysis_test(name, *, is_windows, **kwargs):
+    analysis_test(
+        name = name,
+        attrs = {
+            "is_windows": attr.bool(),
+        },
+        attr_values = {
+            "is_windows": is_windows,
+        },
+        **kwargs
+    )
+
+def cc_test_suite(name, *, tests = [], basic_tests = [], test_kwargs = {}):
+    test_kwargs = dict(test_kwargs, **{
+        "is_windows": select({
+            "@platforms//os:windows": True,
+            "//conditions:default": False,
+        }),
+    })
+    test_suite(
+        name = name,
+        tests = tests,
+        basic_tests = basic_tests,
+        test_kwargs = test_kwargs,
+    )

tests/cc/testutil/cc_analysis_test.bzl

@@ -0,0 +1,30 @@
+"""Tweaked TargetSubject for asserting on a cc_binary target.
+
+Adds a `binary_extension` to the meta info that can be used in format strings that then
+match both Windows and non-Windows targets.
+
+Offers the same interface as TargetSubject, in fact it is just a TargetSubject, with additional
+meta info.
+
+Example use:
+
+cc_binary_target_subject.from_target(env, target).executable().short_path_equals(
+    "{package}/{name}{binary_extension}"
+)
+"""
+
+load("@rules_testing//lib:truth.bzl", "subjects")
+
+def _cc_binary_target_subject_from_target(env, target):
+    helper_target_subject = env.expect.that_target(target)
+    binary_extension = ".exe" if env.ctx.attr.is_windows else ""
+    meta = helper_target_subject.meta.derive(
+        expr = "cc_binary_target({})".format(target.label),
+        details = ["cc_binary_target: {}".format(target.label)],
+        format_str_kwargs = {"binary_extension": binary_extension},
+    )
+    return subjects.target(target, meta)
+
+cc_binary_target_subject = struct(
+    from_target = _cc_binary_target_subject_from_target,
+)

tests/cc/testutil/cc_binary_target_subject.bzl

@@ -0,0 +1,24 @@
+"""Subject for asserting on Link Actions."""
+
+load("@rules_testing//lib:truth.bzl", "subjects")
+load("//tests/cc/testutil:cc_binary_target_subject.bzl", "cc_binary_target_subject")
+
+def _link_action_subject_new(actual, meta):
+    return struct(
+        actual = actual,
+        meta = meta,
+        inputs = lambda: subjects.collection([f.short_path for f in actual.inputs.to_list()], meta = meta.derive("inputs")),
+        outputs = lambda: subjects.collection([f.short_path for f in actual.outputs.to_list()], meta = meta.derive("outputs")),
+        argv = lambda: subjects.collection(actual.argv, meta = meta.derive("argv")),
+    )
+
+def _link_action_subject_from_target(env, target):
+    action_subject = cc_binary_target_subject.from_target(env, target).action_generating(
+        "{package}/{name}{binary_extension}",
+    )
+    return _link_action_subject_new(action_subject.actual, action_subject.meta)
+
+link_action_subject = struct(
+    new = _link_action_subject_new,
+    from_target = _link_action_subject_from_target,
+)