chroma/Justfile at master · alecthomas/chroma · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
set positional-arguments
set shell := ["bash", "-c"]

version := `git describe --tags --dirty --always`
export GOOS := env("GOOS", "linux")
export GOARCH := env("GOARCH", "amd64")

_help:
    @just -l

# Regenerate the supported-languages table in README.md
readme:
    #!/usr/bin/env bash
    GOOS= GOARCH= go -C cmd/chroma run . --list | _tools/format_supported_langs.py --update README.md

# Generate tokentype_string.go
tokentype-string:
    go generate

# Format JavaScript files
format-js:
    biome format --write cmd/chromad/static/index.js cmd/chromad/static/chroma.js

# Regenerate lexers/lexers_gen.go from the embedded lexer definitions
lexer-metadata:
    GOOS= GOARCH= go generate ./lexers

# Check that generated code is in sync with the embedded lexer definitions
check-generated: lexer-metadata
    #!/usr/bin/env bash
    git diff --exit-code lexers/lexers_gen.go || {
        echo "lexers/lexers_gen.go is stale; run 'just lexer-metadata' and commit the result." >&2
        exit 1
    }

# Tidy Go modules
tidy:
    find . -name 'go.mod' -execdir go mod tidy \;

# Build chromad binary
chromad: wasm-exec chroma-wasm
    #!/usr/bin/env bash
    rm -rf build
    mk cmd/chromad/static/index.min.js : cmd/chromad/static/{index,chroma}.js -- \
    	esbuild --platform=browser --format=esm --bundle cmd/chromad/static/index.js --minify --external:./wasm_exec.js --outfile=cmd/chromad/static/index.min.js
    mk cmd/chromad/static/index.min.css : cmd/chromad/static/index.css -- \
    	esbuild --bundle cmd/chromad/static/index.css --minify --outfile=cmd/chromad/static/index.min.css
    cd cmd/chromad && CGOENABLED=0 go build -ldflags="-X 'main.version={{ version }}'" -o ../../build/chromad .

# Copy wasm_exec.js from TinyGo
wasm-exec:
    #!/usr/bin/env bash
    tinygoroot=$(tinygo env TINYGOROOT)
    mk cmd/chromad/static/wasm_exec.js : "$tinygoroot/targets/wasm_exec.js" -- \
    	install -m644 "$tinygoroot/targets/wasm_exec.js" cmd/chromad/static/wasm_exec.js

# Build WASM binary
chroma-wasm:
    #!/usr/bin/env bash
    if type tinygo > /dev/null 2>&1; then
        mk cmd/chromad/static/chroma.wasm : cmd/libchromawasm/main.go -- \
        	tinygo build -no-debug -target wasm -o cmd/chromad/static/chroma.wasm cmd/libchromawasm/main.go
    else
        mk cmd/chromad/static/chroma.wasm : cmd/libchromawasm/main.go -- \
        	GOOS=js GOARCH=wasm go build -o cmd/chromad/static/chroma.wasm cmd/libchromawasm/main.go
    fi

# Upload chromad to server
upload: chromad
    scp build/chromad root@swapoff.org:
    ssh root@swapoff.org 'install -m755 ./chromad /srv/http/swapoff.org/bin && service chromad restart'